// Unity built-in shader source. Copyright (c) 2016 Unity Technologies. MIT license (see license.txt)

Shader "UIMask/Alpha Blended" {
Properties {
    _TintColor ("Tint Color", Color) = (0.5,0.5,0.5,0.5)
    _MainTex ("Particle Texture", 2D) = "white" {}
    _InvFade ("Soft Particles Factor", Range(0.01,3.0)) = 1.0
		//-------------------add----------------------
		_MaskTex("MaskTexture",2D) = "white"{}
	_MinX("Min X", Float) = -10
		_MaxX("Max X", Float) = 10
		_MinY("Min Y", Float) = -10
		_MaxY("Max Y", Float) = 10

		//-------------------add---------------------
}

Category {
    Tags { "Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent" "PreviewType"="Plane" }
    Blend SrcAlpha OneMinusSrcAlpha
    ColorMask RGB
    Cull Off Lighting Off ZWrite Off

    SubShader {
        Pass {

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma target 2.0
            #pragma multi_compile_particles
            #pragma multi_compile_fog

            #include "UnityCG.cginc"

            sampler2D _MainTex;
            fixed4 _TintColor;
			//-------------------add----------------------
			sampler2D _MaskTex;
			float _MinX;
			float _MaxX;
			float _MinY;
			float _MaxY;
			//-------------------add----------------------

            struct appdata_t {
                float4 vertex : POSITION;
                fixed4 color : COLOR;
                float2 texcoord : TEXCOORD0;
                UNITY_VERTEX_INPUT_INSTANCE_ID
            };

            struct v2f {
                float4 vertex : SV_POSITION;
                fixed4 color : COLOR;
                float2 texcoord : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                #ifdef SOFTPARTICLES_ON
                float4 projPos : TEXCOORD2;
                #endif
                UNITY_VERTEX_OUTPUT_STEREO
					//-------------------add----------------------
					float3 vpos : TEXCOORD3;
				//-------------------add----------------------
            };

            float4 _MainTex_ST;

            v2f vert (appdata_t v)
            {
                v2f o;
                UNITY_SETUP_INSTANCE_ID(v);
                UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(o);
                o.vertex = UnityObjectToClipPos(v.vertex);
                #ifdef SOFTPARTICLES_ON
                o.projPos = ComputeScreenPos (o.vertex);
                COMPUTE_EYEDEPTH(o.projPos.z);
                #endif
                o.color = v.color * _TintColor;
                o.texcoord = TRANSFORM_TEX(v.texcoord,_MainTex);
                UNITY_TRANSFER_FOG(o,o.vertex);
				//-------------------add----------------------
				o.vpos = mul(unity_ObjectToWorld, v.vertex).xyz;
				//-------------------add----------------------
                return o;
            }

            UNITY_DECLARE_DEPTH_TEXTURE(_CameraDepthTexture);
            float _InvFade;

            fixed4 frag (v2f i) : SV_Target
            {
                #ifdef SOFTPARTICLES_ON
                float sceneZ = LinearEyeDepth (SAMPLE_DEPTH_TEXTURE_PROJ(_CameraDepthTexture, UNITY_PROJ_COORD(i.projPos)));
                float partZ = i.projPos.z;
                float fade = saturate (_InvFade * (sceneZ-partZ));
                i.color.a *= fade;
                #endif

                fixed4 c = 2.0f * i.color * tex2D(_MainTex, i.texcoord);
                c.a = saturate(c.a); // alpha should not have double-brightness applied to it, but we can't fix that legacy behaior without breaking everyone's effects, so instead clamp the output to get sensible HDR behavior (case 967476)

                UNITY_APPLY_FOG(i.fogCoord, c);


				//-------------------add----------------------
				fixed2 mask_uv = fixed2((i.vpos.x - _MinX) / (_MaxX - _MinX), (i.vpos.y - _MinY) / (_MaxY - _MinY));
				fixed4 mask_col = tex2D(_MaskTex, mask_uv);
				mask_col.a *= (i.vpos.x >= _MinX);
				mask_col.a *= (i.vpos.x <= _MaxX);
				mask_col.a *= (i.vpos.y >= _MinY);
				mask_col.a *= (i.vpos.y <= _MaxY);
				c.a = min(mask_col.a,c.a);
				//clip(mask_col.a - 0.6);
				//return (1, 0, 0, mask_col.a);
				return c;
				//-------------------add----------------------
            }
            ENDCG
        }
    }
}
}