//人物头部使用的shader，跟pdr1比多了自阴影效果。头部渲染不需要UI的灯光效果
Shader "SuYou/PDR1UI"
{
	Properties
	{
		_MainTex("Base 2D", 2D) = "white"{}
		_MaskTex("Mask 2D", 2D) = "white"{}
		_Normal("Normal", 2D) = "white"{}
		_EmissionRatio("EmissionRatio", Range(0, 100)) = 1
		_EnvRatio("_EnvRatio", Range(0, 2)) = 0.4
	}

		SubShader
		{
			Tags{ "Queue" = "AlphaTest+50" "RenderType" = "Opaque" }
			Pass
			{
				Blend SrcAlpha OneMinusSrcAlpha, Zero Zero
				CGPROGRAM
				#pragma vertex vert
				#pragma fragment frag
				#include "UnityCG.cginc"
				#include "CommonCg.cginc"

				struct appdataInput
				{
					float4 vertex : POSITION;
					float2 uv : TEXCOORD0;
					float3 normal:NORMAL;
					float4 tangent : TANGENT;
				};

				struct v2f
				{
					float4 pos : SV_POSITION;
					float2 uv : TEXCOORD0;
					float4 posWorld : TEXCOORD1;
					float3 normalDir : TEXCOORD2;
					float3 tangentDir : TEXCOORD3;
					float3 bitangentDir : TEXCOORD4;
				};

				sampler2D _MainTex, _MaskTex, _Normal;
				float _EmissionRatio, _EnvRatio;

				v2f vert(appdataInput v)
				{
					v2f o;
					o.posWorld = mul(unity_ObjectToWorld, v.vertex);
					o.pos = mul(UNITY_MATRIX_VP, o.posWorld);
					o.uv = v.uv;

					o.normalDir = UnityObjectToWorldNormal(v.normal);
					o.tangentDir = normalize(mul((float3x3)unity_ObjectToWorld, v.tangent.xyz));
					o.bitangentDir = cross(o.normalDir, o.tangentDir) * v.tangent.w;

					return o;
				}

				float4 frag(v2f i) : SV_Target
				{
					float3 mainColor = tex2D(_MainTex, i.uv).rgb;
					mainColor *= mainColor;
					float4 maskColor = tex2D(_MaskTex, i.uv);

					float3 V = normalize(_WorldSpaceCameraPos.xyz - i.posWorld.xyz);

					float3x3 tangentTransform = float3x3(i.tangentDir, i.bitangentDir, i.normalDir);
					float3 N = UnpackNormal(tex2D(_Normal, i.uv));
					N = normalize(mul(N, tangentTransform));

					float Metallic = maskColor.r;
					float Roughness = max(maskColor.g, 0.008);


					half Specular = 0.5;
					half DielectricSpecular = 0.08 * Specular;
					float3 DiffuseColor = mainColor - mainColor * Metallic;
					float3 SpecularColor0 = (DielectricSpecular - DielectricSpecular * Metallic) + mainColor * Metallic;

					float3 L = _GlobalLightDir1.xyz;
					float3 H = normalize(L + V);

					float4 resultColor = 0;
					float NdotL = max(dot(N, L), 0.0001);
					float NdotV = max(dot(N, V), 0.0001);
					float NdotH = max(dot(N, H), 0.01);
					float3 SpecularColor = EnvBRDFApprox(SpecularColor0, Roughness, NdotV);
					float3 specular = SpecularColor * (Roughness * 0.25 + 0.25) * GGX_Mobile(Roughness, NdotH);
					resultColor.rgb = (DiffuseColor + specular) * _GlobalDirColor * NdotL;

					resultColor.rgb += _EnvRatio * mainColor;
					resultColor.rgb += maskColor.b * mainColor * _EmissionRatio;
					resultColor.rgb = sqrt(resultColor.rgb);

					resultColor.a = 1;
					return resultColor;
				}
				ENDCG
			}
    }
	FallBack "Diffuse"
}