Shader "SuYou/PDR3Alpha"
{
	Properties
	{
		_MainTex("Base 2D", 2D) = "white"{}
		_MaskTex("Mask 2D", 2D) = "white"{}
		_Normal("Normal", 2D) = "white"{}
		_EnvTex("Env Texture", Cube) = "" {}
		_CameraLightColor("CameraLightColor", Color) = (0.9,0.9,0.9,1)
		_EmissionRatio("EmissionRatio", Range(0, 100)) = 1
		_EnvTexRatio("EnvTexRatio", Range(0, 2)) = 1
		_EnvRatio("_EnvRatio", Range(0, 2)) = 0.0
	}

	CGINCLUDE
		#include "UnityCG.cginc"
		#include "CommonCg.cginc"
		sampler2D _MainTex, _MaskTex, _Normal;
		samplerCUBE _EnvTex;
		float _EnvTexRatio, _EmissionRatio, _EnvRatio;
		float4 _CameraLightColor;
		/*float4 _GlobalLightDir, _GlobalLightDir1;
		float4 _GlobalDirColor, _GlobalPointColor0, _GlobalPointColor1, _GlobalPointColor2, _GlobalPointColor3;
		float4 _GlobalPointX, _GlobalPointY, _GlobalPointZ, _GlobalPointAtten;*/

		struct appdataInput
		{
			float4 vertex : POSITION;
			float2 uv : TEXCOORD0;
			float3 normal:NORMAL;
			float4 tangent : TANGENT;
		};

		struct v2f
		{
			float4 pos : SV_POSITION;
			float2 uv : TEXCOORD0;
			float4 posWorld : TEXCOORD1;
			float3 normalDir : TEXCOORD2;
			float3 tangentDir : TEXCOORD3;
			float3 bitangentDir : TEXCOORD4;
		};

		v2f vert(appdataInput v)
		{
			v2f o;
			o.posWorld = mul(unity_ObjectToWorld, v.vertex);
			o.pos = mul(UNITY_MATRIX_VP, o.posWorld);
			o.uv = v.uv;

			o.normalDir = UnityObjectToWorldNormal(v.normal);
			o.tangentDir = normalize(mul((float3x3)unity_ObjectToWorld, v.tangent.xyz));
			o.bitangentDir = cross(o.normalDir, o.tangentDir) * v.tangent.w;

			return o;
		}

		float4 frag(v2f i) : SV_Target
		{
			float4 cc = tex2D(_MainTex, i.uv);
			float3 mainColor = cc.rgb;
			mainColor *= mainColor;
			float4 maskColor = tex2D(_MaskTex, i.uv);

			float3 V = normalize(_WorldSpaceCameraPos.xyz - i.posWorld.xyz);

			float3x3 tangentTransform = float3x3(i.tangentDir, i.bitangentDir, i.normalDir);
			float3 N = UnpackNormal(tex2D(_Normal, i.uv));
			N = normalize(mul(N, tangentTransform));

			float3 R = reflect(-V, N);

			float Metallic = maskColor.r;
			float Roughness = max(maskColor.g, 0.008);

			//half3 DiffuseColor = mainColor;
			//half SpecularColor0 = 0.04;
			half Specular = 0.5;
			half DielectricSpecular = 0.08 * Specular;
			float3 DiffuseColor = mainColor - mainColor * Metallic;
			float3 SpecularColor0 = (DielectricSpecular - DielectricSpecular * Metallic) + mainColor * Metallic;

			float3 L = _GlobalLightDir.xyz; //;
			float3 H = normalize(L + V);

			float4 resultColor = 0;
			float NdotL = max(dot(N, L), 0.0001);
			float NdotV = max(dot(N, V), 0.0001);
			float NdotH = max(dot(N, H), 0.01);
			float3 SpecularColor = EnvBRDFApprox(SpecularColor0, Roughness, NdotV);
			float3 specular = SpecularColor *  (Roughness * 0.25 + 0.25) * GGX_Mobile(Roughness, NdotH);
			resultColor.rgb = (DiffuseColor + specular) * _CameraLightColor * NdotL;

			L = _GlobalLightDir1.xyz;
			H = normalize(L + V);
			NdotL = max(dot(N, L), 0.0001);
			NdotH = max(dot(N, H), 0.01);
			specular = SpecularColor *  (Roughness * 0.25 + 0.25) * GGX_Mobile(Roughness, NdotH);
			resultColor.rgb += (DiffuseColor + specular) * _GlobalDirColor * NdotL;

			resultColor.rgb += BRDFPointLights(i.posWorld.xyz, V, N, DiffuseColor, SpecularColor0, Roughness);

			float mipIndex = Roughness * 6;
			float4 rgbm = texCUBElod(_EnvTex, float4(R, mipIndex));
			float3 ibl = rgbm.rgb * 2;
			ibl *= ibl;

			//resultColor.rgb += ibl * SpecularColor * _EnvTexRatio * maskColor.a;
			//测试
			resultColor.rgb += ibl * SpecularColor0 * _EnvTexRatio * maskColor.a;

			//美术反映有些透明叠加的效果不理想，参考了pdr1来改
			resultColor.rgb += _EnvRatio * mainColor;
			resultColor.rgb += maskColor.b * mainColor * _EmissionRatio;
			resultColor.rgb = sqrt(resultColor.rgb);

			resultColor.a = cc.a;
			return resultColor;
		}

	ENDCG
 
	SubShader
	{
		Tags{ "Queue" = "AlphaTest+100" "RenderType" = "Transparent" }
		//Blend SrcAlpha OneMinusSrcAlpha
		Blend SrcAlpha OneMinusSrcAlpha, Zero Zero
	
		Pass
		{
			Cull Front
			//ZWrite Off
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			ENDCG
		}

		Pass
		{
			Cull Back
			//ZWrite Off
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			ENDCG
		}
	}
}